ipxe/src/menu.ipxe

#!ipxe

# ipxe menu (stargazer.socialnerds.org)

#:dhcp
dhcp net0 || goto dhcp

colour --basic 9 4
colour --basic 6 1

# configuration
set server_name stargazer.socialnerds.org
set server_ip ${net0/gateway}
set iscsi_portal 10.1.5.2
set iqn-discovery-esxi iscsi:${iscsi_portal}::::iqn.2000-01.com.synology:spacedock.discovery-esxi.e84d7761fd
set iqn-ghost-windows81 iscsi:${iscsi_portal}::::iqn.2000-01.com.synology:spacedock.ghost-windows81.e84d7761fd 
set iqn-ghost-archlinux iscsi:${iscsi_portal}::::iqn.2000-01.com.synology:spacedock.ghost-archlinux.e84d7761fd 
set iqn-ghost-antergos iscsi:${iscsi_portal}::::iqn.2000-01.com.synology:spacedock.ghost-antergos.e84d7761fd 

:custom
#iseq ${net0/ip} 10.1.5.4 && goto ${net0/ip} || goto menu
goto ${net0/ip} || goto menu

:menu
menu stargazer.socialnerds.org
item --gap MAC Address: ${net0/mac}
item --gap IP Address: ${net0/ip}
item --gap Netmask: ${net0/netmask}
item --gap Gateway: ${net0/gateway}
item --gap DNS: ${net0/dns}
item
item
item noboot    Here be dragons.
item

choose target && goto ${target}
goto menu

:windows81
echo Booting into Windows 8.1 from ISCSI.
set net0/keep-san 1
sleep 1
sanboot --keep ${iqn-ghost-windows81} || goto menu

:archlinux
echo Booting into Archlinux from ISCSI.
set net0/keep-san 1
sleep 1
sanboot --keep ${iqn-ghost-archlinux} || goto menu

:antergos
echo Booting into Antergos from ISCSI.
set net0/keep-san 1
sleep 1
sanboot --keep ${iqn-ghost-antergos} || goto menu

# Custom boot for 10.1.5.4 (discovery_iscsi)
:10.1.5.4
echo Booting into VMWare ESXi 6.5 from ISCSI.
set net0/keep-san 1
sanboot --keep ${iqn-discovery-esxi} || goto menu

# Custom boot for 10.1.5.3 (ghost_iscsi)
:10.1.5.3
menu stargazer.socialnerds.org
item --gap MAC Address: ${net0/mac}
item --gap IP Address: ${net0/ip}
item --gap Netmask: ${net0/netmask}
item
item
item antergos       Boot into Antergos
item archlinux      Boot into Archlinux
item windows81      Boot into Windows 8.1
item

choose target && goto ${target}
goto menu